[GTER] MX e Spammers

[Danton Nunes]

On Thu, 8 May 2003, Silmar A. Marca wrote:

> A propósito: tenho uma lista rbl aqui em meu servidor (rbl.grupogsn.com.br), as 
> o problema é ficar atualizando arquivos texto. Alguem conhece uma maneira de 
> transformar o named-bind para consultar bd em mysql ou algo parecido? Se alguem 
> souber de um site, ou pacote por favor me avise...

o script em anexo é o que eu uso para manter a minha lista. para remover, só
editando na mão mesmo. para adicionar, basta filtrar a mensagem pelo script.

ele usa o cabeçalho 'received' mais recente. note que ele descarta 'received's
de ip's amigos e leva em conta 'x-received' para tratar mensagens redirigidas.

danton
-------------- next part --------------
#!/usr/bin/awk -f
#
#	Achtung: Este programa serve para matar mensgens indesejados e
#	mandá-las para o ralo. É um aperfeiçoamento de um script anterior
#	em 'sed' e um bom exercicio de programação em 'awk'.
#
#	O endereço do último relay (que não seja um dos nossos ;-) vai 
#	para a lista negra. O texto inteiro da mensagem vai para 'lixo',
#	que é o lugar apropriado.
#
#	Copyright, copyleft, copyup & copydown © 2001 InterNexo Ltda.
#
#	modificado em 11-maio-2k+1: todo o classe C a que pertencer o 
#	endereço vai pro beleléu junto. trocando ipf[4] por "*" no printf. 
#
BEGIN	{ noismemo="200\.231\.(4[8-9]|5[0-6])\.[0-9]+"; IGNORECASE=1; }
	{ print >"lixo" }
/^$/	{ b=1 }
b	{ next }
r && /^[[:blank:]]/	{ ip=ip $0 ; next }
r	{ sub(/[^[]*\[/,"",ip); sub(/\].*/,"",ip);
	  if (ip ~ noismemo || ip !~ /[0-9]+\.[0-9]+\.[0-9]+\.[0-9]+/ ) { r=0; ip="" }
	  else { split(ip,ipf,/[.]/);
	    printf("%s.%s.%s.%s\tin\ta\t127.0.0.2\n",
	      "*",ipf[3],ipf[2],ipf[1]) >>"/var/named/blackhole.db";
	    r=0; b=1; next } }
/^(x-)?received:/ { ip=$0; r=1; next }
END	{ printf("in dubio ad niger cavus (%s)\n",ip) }